eingehende Handyanrufe am PC anzeigen lassen?

[MBMBMB]

Hallo,

ist es mit MyPhoneExplorer möglich eingehende Anrufe vom Handy am PC so anzeigen zu lassen, dass der entsprechende Kontakt direkt in Outlook geöffnet wird?

Hintergrund ist, da sämtliche Kontaktdaten im Outlook Business Contact Manager hinterlegt sind und auch von der Telefonanlage eingehende Anrufe somit dort als Journaleintrag automatisch erfast werden und Gesprächsnotitzen so hinzugefügt werden können.

[FJ]

MyPhoneExplorer verwaltet die Anrufe selbst, eine Verlinkung mit Outlook ist hier nicht geplant. Aber mit ein bischen Scripting kannst du da sicher was machen. Siehe FAQ (ganz unten - EventHandler)

[MBMBMB]

Danke für die Rückmeldung,

leider habe ich selbst keinerlei Ahnung von Scripten oder Programmieren

Wenn mir jemand dabei helfen kann damit ich das auch umsetzen kann wäre ich sehr dankbar, da unbedingt die Anbindung eines Mobiltelefones an den PC und darüber das Öffnen der jeweiligen Outlookkontakte darauf benötige. Dies wird dann auf mehreren PCs/Einzelstationen benötigt.

Vielen Dank

[FJ]

Ich habe Outlook Business Contact Manager nicht weshalb ich dir da schlecht weiterhelfen kann, vielleicht findest du ja einen Outlook-Spezi der dir das bastelt

[MBMBMB]

Hallo FJ,

der Business Contact Manager integriert sich komplett in Outlook. Somit reicht es wenn im normalen Outlook die Kontakte geöffnet werden. Wenn das gehen würde wäre das super und ich hätte endlich eine Lösung gefunden.

[FJ]

Erstelle die Datei C:\DisplayOutlookContact.vbs und editirere sie mit Notepad folgendermaßen:

Code: Alles auswählen

If WScript.Arguments.Count > 0 Then
  Call FindContact(WScript.Arguments.Item(0))
End If


Sub FindContact(Number)
    Dim olApp
    Dim objResult
    Dim objContacts
    Dim objNameSpace
    Dim sFilter

    Const tMobile = """http://schemas.microsoft.com/mapi/proptag/0x3A1C001F"""
    Const tBusiness = """http://schemas.microsoft.com/mapi/proptag/0x3A08001F"""
    Const tBusiness2 = """http://schemas.microsoft.com/mapi/proptag/0x3A1B001F"""
    Const tHome = """http://schemas.microsoft.com/mapi/proptag/0x3A09001F"""
    Const tHome2 = """http://schemas.microsoft.com/mapi/proptag/0x3A2F001F"""

    If Len(Number) < 5 Then Exit Sub

    sFilter = Number

    'MyPhoneExplorer übergibt die Nummer im Format "Name [Nummer]", wir müssen die Nummer rausfiltern
    If Instr(1,sFilter,"[") <> 0 Then
      sFilter = Mid(sFilter, InstrRev(sFilter,"[") + 1)
      If Instr(1, sFilter, "]") <> 0 Then
        sFilter = Left(sFilter, Instr(1, sFilter, "]") - 1)
      End If
    End If

    'Ländervorwahl und führende 0 der nationalen Vorwahl wegschneiden
    If Left(sFilter, 2) = "00" Then sFilter = Mid(sFilter,5)
    If Left(sFilter, 1) = "+" Then sFilter = Mid(sFilter,4)
    If Left(sFilter, 1) = "0" Then sFilter = Mid(sFilter,2)
    sFilter = " like '%" & sFilter & "'" 

    Set olApp = CreateObject("Outlook.Application")
    Set objNameSpace = olApp.GetNamespace("MAPI")
    Set objContacts = objNameSpace.GetDefaultFolder(10)

    Set objResult = objContacts.Items.Find("@SQL=" & tMobile & sFilter & " OR " & tBusiness & sFilter & " OR " & tBusiness2 & sFilter & " OR " & tHome & sFilter & " OR " & tHome2 & sFilter)

    If TypeName(objResult) <> "Nothing" Then
        objResult.Display
    Else
        MsgBox "Kontakt nicht gefunden zu: " & Number
    End If
End Sub

Öffne dann die Datei %appdata%\MyPhoneExplorer\general.ini mit Notepad und hänge unten folgendes an:

Code: Alles auswählen

[EventHandlers]
OnIncomingCall=C:\DisplayContactOutlook.vbs "%number"

Wenn du alles richtig machst dann wird ab jetzt bei jedem eingehenden Anruf der passende Outlook-Kontakt angezeigt. Gesucht wird in den Outlook Feldern: Mobil, Geschäftlich, Geschäftlich 2, Privat und Privat 2

[EmPeSofti]

Hallo FJ

Auch wenn mich obiges Problem überhaupt nicht betrifft. Ich finde es erstaunlich und bemerkenswert, mit wieviel Engagement und Aufwand Du Userprobleme beantwortest!

Das darf doch als Lob an Dich auch Mal "öffentlich" gesagt werden )

Gruss aus der Schweiz. Peter

[FJ]

Danke fürs Lob

Ich muss aber eingestehen daß ich das aus zeitlichen Gründen nicht immer mache. Hier hats mich halt einfach in den Fingern gejuckt

Aber so wie es aussieht wars eh für die Katz, sonst hätte der Thread-Ersteller wohl nochmal geantwortet